Excel BI Challenge Workout 198

LinkedIn Post by:
Hussein SATOUR

Thank you Excel BI

=LET(a, A2:A10, b, B2:B10, BYROW(IFERROR(HSTACK(a+b, a-b, a*b, a/b)=C2:C10,0), LAMBDA(x, TEXTJOIN(", ",, FILTER({"+","-","*","/"},x)))))

LinkedIn Post by:
Bo Rydobon

=MAP(A2:A10,B2:B10,C2:C10,LAMBDA(a,b,c,TEXTJOIN(", ",,REPT({"+","-","*","/"},HSTACK(a+b,a-b,a*b,IF(b,a/b))=c))))

LinkedIn Post by:
Bo Rydobon

=MAP(A2:A10,B2:B10,C2:C10,LAMBDA(a,b,c,ARRAYTOTEXT(FILTER({"+","-","*","/"},HSTACK(a+b,a-b,a*b,IF(b,a/b))=c))))

LinkedIn Post by:
Guillermo Arroyo

=MAP(A2:A10,B2:B10,C2:C10,LAMBDA(a,b,c,TEXTJOIN(", ",1,FILTER({"+";"-";"*";"/"},VSTACK(a+b,a-b,a*b,IFERROR(a/b,""))=c,""))))

LinkedIn Post by:
Julien Lacaze

=LET(_n1,A2:A10,_n2,B2:B10,_r,C2:C10,
_add,--((_n1+_n2)=_r),
_sub,--((_n1-_n2)=_r),
_mul,--((_n1*_n2)=_r),
_div,--(IFERROR(_n1/_n2,"")=_r),
MAP(_add,_sub,_mul,_div,LAMBDA(a,s,m,d,TEXTJOIN(", ",TRUE,IF(a,"+",""),IF(s,"-",""),IF(m,"*",""),IF(d,"/",""))
)))

LinkedIn Post by:
محمد حلمي

=LET(a,A2:A10,b,B2:B10,BYROW(IFERROR(HSTACK(a+b,a-b,a*b,a/b)=C2:C10,),LAMBDA(a,TEXTJOIN(", ",,REPT({"+","-","*","/"},a)))))

LinkedIn Post by:
Daniel G.

=MAP(A2:A10,B2:B10,C2:C10,LAMBDA(a,b,r,TEXTJOIN(", ",,IF(VSTACK(a+b,a-b,a*b,IFERROR(a/b,""))=r,{"+";"-";"*";"/"},""))))

LinkedIn Post by:
Surendra Reddy

=MAP(A2:A10,B2:B10,C2:C10,LAMBDA(x,y,z,TEXTJOIN(", ",,IF(x+y=z,"+",""),IF(x-y=z,"-",""),IF(x*y=z,"*",""),IF((IFERROR(x/y,"")=z),"/",""))
))

LinkedIn Post by:
Zoran Milokanović

Listing operators w/ hashtag#powerquery. hashtag#bitanbit hashtag#powerbi

let
Source = Excel.CurrentWorkbook(){[Name="Input"]}[Content],
Solution = Table.TransformRows(Source, (o) => Text.Combine(List.Select({"+", "-", "*", "/"}, each Expression.Evaluate(Text.From(o[Number1]) & _ & Text.From(o[Number2]) & "=" & Text.From(o[Result]))), ", "))
in
Solution