Excel BI Challenge Workout 196

Workouts Excel BI Challenge
21

LinkedIn Post by:
Surendra Reddy

=MAP(A2:A6,LAMBDA(x,TEXTJOIN("-",,REPT(MID(x,SEQUENCE(LEN(x)),1),SEQUENCE(LEN(x))))))

22

LinkedIn Post by:
Hussain Ali Nasser
 

=BYROW(A2:A6,LAMBDA(_range,LET(_split,MID(_range,SEQUENCE(LEN(_range)),1),_seq,SEQUENCE(LEN(_range)),_result,TEXTJOIN("-",,REPT(_split,_seq)),_result)))
23

LinkedIn Post by
Amr Tawfik, CMA P1

here is what come to my mind

=MAP(A2:A6,LAMBDA(x,TEXTJOIN("-",TRUE,REPT(MID(x,SEQUENCE(LEN(x),1,1),1),SEQUENCE(LEN(x),,1,1)))))

24

LinkedIn Post by:
Rick Rothstein

=MAP(A2:A6,LAMBDA(a,LET(s,SEQUENCE(LEN(a)),TEXTJOIN("-",,REPT(MID(a,s,1),s)))))

25

LinkedIn Post by:
[

John Jairo V.

](https://www.linkedin.com/in/ACoAAAqPXQwB8CH0RQruOF3bbvf0SX2t-z9pPLg)

Hi to all!

One option could be:
:white_check_mark:

=MAP(A2:A6,LAMBDA(x,TEXTJOIN("-",,REPT(MID(x,ROW(1:9),1),ROW(1:9)))))

Blessings!

26

LinkedIn Post by:
Stevenson Yu

Today was quite a nice breather, with the REPT function.

=MAP(A2:A6,LAMBDA(X,LET(A,X,
B, SEQUENCE(LEN(A)),
TEXTJOIN("-",,REPT(MID(A,B,1),B)))))
27

LinkedIn Post by:
[

Oscar Mendez Roca Farell

](https://www.linkedin.com/in/ACoAAA6zDE4Bt5G7qmkAGrxIvbPLBBRDss3L4Gk)

hi everyone, my proposal solution:

=MAP(A2:A6, LAMBDA(a, LET(_s, SEQUENCE(, 5), TEXTJOIN("-", 1, REPT(MID(a,_s, 1),_s)))))

28

LinkedIn Post by
Miguel Angel Franco García

Envio mi soluccion

=UNIRCADENAS("-";VERDADERO;LET(a;EXTRAE(A2;SECUENCIA(LARGO(A2));1);b;FILAS(a);c;SECUENCIA(b);REPETIR(a;c)))

29

LinkedIn post by:
Daniel G.

=BYROW(A2:A6,LAMBDA(x,LET(l,SEQUENCE(LEN(x)),TEXTJOIN("-",,REPT(MID(x,l,1),l)))))

30

LinkedIn Post by:
Bo Rydobon

=SUBSTITUTE(TRIM(REDUCE("",SEQUENCE(9),LAMBDA(a,n,a&" "&REPT(MID(A2:A6,n,1),n))))," ","-")

31

LinkedIn post by:
[

Guillermo Arroyo

](https://www.linkedin.com/in/ACoAAAEZJRQBQC3dIt3x6CkmvxbNRJchjuuFIvc)

=MAP(A2:A6,LAMBDA(a,TEXTJOIN("-",1,REDUCE("",SEQUENCE(LEN(a)),LAMBDA(i,j,VSTACK(i,REPT(MID(a,j,1),j)))))))

32

LinkedIn post by:
Hussein SATOUR

Thank you Excel BI

=MAP(A2:A6, LAMBDA(x, LET(a, SEQUENCE(LEN(x)), TEXTJOIN("-",, REPT(MID(x,a,1), a)))))

33

LinkedIn post by
Julien Lacaze

=MAP(A2:A6,LAMBDA(a,TEXTJOIN("-",TRUE,REPT(MID(a,SEQUENCE(LEN(a)),1),FIND(MID(a,SEQUENCE(LEN(a)),1),a)))))

Edit :
Only works for single letter occurrence…

This one should give more accurate results :

=MAP(A2:A6,LAMBDA(a,TEXTJOIN("-",TRUE,REPT(MID(a,SEQUENCE(LEN(a)),1),SEQUENCE(LEN(a))))))

Bonus :
Revert From the answer to initial String :

=MAP(B2:B6,LAMBDA(a,TEXTJOIN("",TRUE,LEFT(TEXTSPLIT(a,"-")))))