Excel BI Challenge Workout 184

Workouts Excel BI Challenge
21

LinkedIn Post by:
Taeyong Shin
 

=LET(
 y, SEQUENCE(99, , 2001),
 s, y & -SEQUENCE(, 12) & -1,
 e, EOMONTH(s, 0),
 FILTER(y, MMULT(N(NETWORKDAYS.INTL(s, e, "1111000") = 15), SIGN(SEQUENCE(12))) = 2)
)
22

LinkedIn Post by:
Bo Rydobon

=TOCOL(MAP(SEQUENCE(100,,2000),LAMBDA(y,LET(d,y&-SEQUENCE(12)&-1,y/(2=SUM((MOD(d,7)=6)*(EDATE(d,1)-d=31)))))),3)

23

LinkedIn Post by
Stevenson Yu

I noticed that this challenge never said we can’t hardcode the answer. Soooooo…

=CODE(MID("&,17BHMS^dioz",SEQUENCE(13),1))+1972

:grin::grin::grin:

24

LinkedIn Post by:
Gabriel Raigosa

:arrow_forward:EN:

=LET(d,SEQUENCE(36525,,36526,1),Y,SEQUENCE(100,,2000,1),FILTER(Y,BYROW(Y,LAMBDA(y,SUMPRODUCT(((DAY(d)=31)*(WEEKDAY(d,2)=7)=1)*(YEAR(d)=y))))=2))

:arrow_forward:ES:

=LET(d,SECUENCIA(36525,,36526,1),Y,SECUENCIA(100,,2000,1),FILTRAR(Y,BYROW(Y,LAMBDA(y,SUMAPRODUCTO(((DIA(d)=31)*(DIASEM(d,2)=7)=1)*(AÑO(d)=y))))=2))

25

LinkedIn Post by:
Caroline Blake
 

=LET(
d,DATE(SEQUENCE(100,,2000,1),{1,3,5,7,8,10,12},31),
y,UNIQUE(YEAR(d),TRUE),
FILTER(y,BYROW(d,LAMBDA(d,SUM(--(WEEKDAY(d)=1))))>1))